Domaine concerné: Utilitaire
Logiciel utilisé: RPG Maker 2000 Value
Coucou,
Pour ceux qui utilisent rm2000 et 2003, vous avez peut-être remarqué que la version steam de rm2003 dispose d'un launcher dans le dossier de projet, qui permet de lancer l'éditeur sans passer par ouvrir > chercher le dossier de jeu, ce qui pouvait donner lieu à des temps d'attente interminables.
Etant moi-même incapable de le faire, Mack a bien voulu écrire un fichier batch (.bat) pour pouvoir faire la même chose avec un jeu rm2000 (value).
Je laisse ça ici pour ceux que ça intéresserait.
Pour l'utiliser, il suffit de copier la portion de code ci-dessous dans un bloc-notes, à renommer comme vous voulez avec l'extension .bat
Pour l'utiliser, il suffit de le placer dans le dossier de jeu de rm2000 (avec les fichiers .lmu) et de l'exécuter.
Ne fonctionne que sur Windows, testé sur Windows 10.
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
| @ECHO off
Rem Les deux lignes suivantes vont servir à modifier les registres de RM2000 pour y inscrire le nom du dossier courant
for %%I in (.) do set CurrDirName=%%~nxI
REG ADD "HKEY_CURRENT_USER\SOFTWARE\KADOKAWA\RPG2000" /v "OpenedProjectFolder" /t REG_SZ /d "%CurrDirName%" /f
for %%I in ("%~dp0.") do for %%J in ("%%~dpI.") do set ParentFolderName=%%~dpnxJ
REG ADD "HKEY_CURRENT_USER\SOFTWARE\KADOKAWA\RPG2000" /v "ProjectBasePath" /t REG_SZ /d "%ParentFolderName%/" /f
set KEY_NAME="HKEY_CURRENT_USER\SOFTWARE\KADOKAWA\RPG2000"
set VALUE_NAME=ApplicationPath
setlocal ENABLEEXTENSIONS
Rem Cette boucle permet de récuperer le dossier d'installation de RM2000 pour y trouver le rm2000.exe
for /F "usebackq tokens=1,2,*" %%A IN (`reg query "%KEY_NAME%" /v "%VALUE_NAME%" 2^>nul ^| find "%VALUE_NAME%"`) do (
set EXE_FILE=%%C
)
Rem Permet de lancer RM2000 selon son dossier d'installation
Start "" "%EXE_FILE%rpg2000.exe" |
| 
Chat
